1 files changed, 59 insertions, 0 deletions
diff --git a/mingw-w64-raylib-static/PKGBUILD b/mingw-w64-raylib-static/PKGBUILD
new file mode 100644
index 0000000..365b196
--- /dev/null
+++ b/mingw-w64-raylib-static/PKGBUILD
@@ -0,0 +1,59 @@
+_pkgname=mingw-w64-raylib
+pkgname=mingw-w64-raylib-static
+pkgver=4.2.0
+pkgrel=1
+pkgdesc="Simple and easy to use game programming library (mingw-w64)"
+arch=(any)
+url="https://www.raylib.com"
+license=(ZLIB)
+# Use internal GLFW for now, since the bundled GLFW is newer
+#depends=(mingw-w64-crt mingw-w64-glfw)
+depends=(mingw-w64-crt)
+makedepends=(mingw-w64-cmake)
+provides=($_pkgname)
+conflicts=($_pkgname)
+options=(!strip !buildflags staticlibs)
+install=
+source=(
+    "raylib_${pkgver}.tar.gz::https://github.com/raysan5/raylib/archive/refs/tags/${pkgver}.tar.gz"
+    'raylib_glfw.patch'
+)
+noextract=()
+md5sums=(
+    8b63a4d4a1e4356fc332fa16eb85d87e
+    a44c1130eac923910f3047696c9a7363
+)
+
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+prepare() {
+    cd "$srcdir/raylib-${pkgver}"
+    patch -p1 < "$srcdir/raylib_glfw.patch"
+}
+
+build() {
+    for _arch in ${_architectures}; do
+        mkdir -p "$srcdir/build_${_arch}"
+        pushd "$srcdir/build_${_arch}"
+        "${_arch}-cmake" "$srcdir/raylib-${pkgver}" \
+            -Wno-dev \
+            -D CMAKE_BUILD_TYPE=Release \
+            -D CMAKE_C_FLAGS="$CFLAGS -w" \
+            -D USE_EXTERNAL_GLFW=OFF \
+            -D BUILD_EXAMPLES=OFF \
+            -D BUILD_GAMES=OFF \
+            -D SHARED=ON \
+            -D STATIC=OFF
+        make -j
+        popd
+    done
+}
+
+package() {
+    for _arch in ${_architectures}; do
+        pushd "$srcdir/build_${_arch}"
+        DESTDIR="$pkgdir" make install
+        ${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
+        popd
+    done
+}