project(library CXX)
add_library(${PROJECT_NAME} SHARED
	src/client.cpp
	src/gpio.cpp
	src/memory.cpp
	src/sinewave.cpp
	)
target_link_libraries(${PROJECT_NAME}
	PUBLIC rpclib::rpc
	PUBLIC Threads::Threads
	PRIVATE config
	)
target_include_directories(${PROJECT_NAME}
	PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
	PUBLIC "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
	)
set_target_properties(${PROJECT_NAME}
	PROPERTIES OUTPUT_NAME hwd
	)
configure_package_config_file(
	cmake/Config.cmake.in
	${CMAKE_CURRENT_BINARY_DIR}/HwdConfig.cmake
	INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/Hwd
	)
configure_file(hwd.pc.in hwd.pc @ONLY)
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/hwd.pc
	DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
	)
install(TARGETS ${PROJECT_NAME}
	EXPORT HwdTargets
	RUNTIME
	INCLUDES
	)
install(FILES include/hwd.h
	DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
	)
install(EXPORT HwdTargets
	FILE HwdTargets.cmake
	NAMESPACE Hwd::
	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/Hwd
	)
install(FILES
	${CMAKE_CURRENT_BINARY_DIR}/HwdConfig.cmake
	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/Hwd
	)