From f4a82177f3bea3e744cbc4acbd052fc7be31cab1 Mon Sep 17 00:00:00 2001
From: Aki <please@ignore.pl>
Date: Mon, 13 Mar 2023 01:16:11 +0100
Subject: Replaced raylib-both with just -static version

Current CMake+pkg-config configuration provided with raylib does not
properly handle case in which both library version are available.
---
 raylib-static/PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 raylib-static/PKGBUILD

(limited to 'raylib-static/PKGBUILD')

diff --git a/raylib-static/PKGBUILD b/raylib-static/PKGBUILD
new file mode 100644
index 0000000..f92cdaa
--- /dev/null
+++ b/raylib-static/PKGBUILD
@@ -0,0 +1,37 @@
+_pkgname=raylib
+pkgname=raylib-static
+pkgver=4.2.0
+pkgrel=1
+pkgdesc='Simple and easy-to-use game programming library'
+provides=($_pkgname)
+conflicts=($_pkgname)
+options=(staticlibs)
+arch=(x86_64)
+url='https://www.raylib.com'
+license=(ZLIB)
+makedepends=(cmake git libx11 libxcursor libxinerama libxrandr ninja vulkan-headers xorg-server-devel xorg-xinput)
+source=("git+https://github.com/raysan5/raylib#commit=bf2ad9df5fdcaa385b2a7f66fd85632eeebbadaa")
+b2sums=('SKIP')
+
+build() {
+  cmake \
+    -B static \
+    -D BUILD_EXAMPLES=OFF \
+    -D BUILD_SHARED_LIBS=OFF \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D CMAKE_C_FLAGS="$CFLAGS -w" \
+    -D CMAKE_INSTALL_LIBDIR=lib \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D OpenGL_GL_PREFERENCE=GLVND \
+    -D USE_EXTERNAL_GLFW=OFF \
+    -G Ninja \
+    -S $_pkgname \
+    -W no-dev
+  ninja -C static
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C static install
+  install -Dm 644 "$_pkgname/LICENSE" \
+    "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+}
-- 
cgit v1.1